File:Estimations of Human Brain Emulation Required Performance.svg

set terminal svg size 800 600 fname "Times"
 set output "Estimations of Human Brain Emulation Required Performance.svg"
 set notitle
 set key reverse Left left at 1993, 10**40 noautotitles box # good chunk of whitespace to put the key in
 set datafile separator "," # csv formatted using commas; redundant, but makes it easy to keep track

 set logscale y # use a logarithmic scale, for easier visualization of exponential growth
 set yrange[10**9:10**45]
 set ylabel "Flop/s"

 set xrange [1990:2065]
 set xlabel "Year"
 set xtics 1990,5,2065
 set mxtics 5
 #set grid # I think it looks better without, but it's a matter of preference

 # labels for each of the levels of emulation
 set label "Analog network population model" at 2010, 10**14.5 left
 set label "Spiking neural network" at 2015, 10**17.5 right
 set label "Electrophysiology" at 2033.5, 10**22.5 right
 set label "Metabolome" at 2044.5, 10**25.5 right
 set label "Proteome" at 2048, 10**26.5 right
 set label "States of protein complexes" at 2052, 10**27.5 right
 set label "Distribution of complexes" at 2062.5, 10**30.5 right
 set label "Stochastic behavior of single molecules" at 2064, 10**42.5 right

 set label "Functional Simulation" at 2016, 10**16.5 left
 set label "Neural Simulation" at 2028, 10**19.5 left

 # trendline is sort of ad hoc, just picked a date towards the middle of the data and did a best-fit
 # horizontal lines plotted to represent levels of emulation, linestyle 3 and 2 because I liked the colors or something
 # plot of historical TOP500 #1's stored in a .csv, colors and sizes picked from what I thought was easiest to see
 # titles done for one of each type of line, for the key
 plot 136800000000000*(2**((x-2005)/1.1)) lw 6 pt 3 lc 0 w lines title "Trendline (doubling every 1.1 years)",\
 10**15 ls 3, 10**18 ls 3, 10**22 ls 3, 10**25 ls 3, 10**26 ls 3, 10**27 ls 3, 10**30 ls 3, 10**43 ls 3 title "Sandberg, Bostrom estimates (2008)",\
 10**16 ls 2, 10**19 ls 2 title "Kurzweil estimates (2005)",\
 "TOP500.csv" using 1:2 ls 1 pt 7 ps .5 with linespoints title "Fastest Supercomputer (TOP500 #1)"